Fso를 이용한 메일보내기 소스

잊어먹을까 봐서... 으음... Fso로 Html 가져오고.. CDOSYS를 이용 메일를 송신한다..

ㅎㅎㅎㅎㅎ 쉽다...

<!--METADATA TYPE="TypeLib" NAME="CDO for Windows 2000 Type Library" UUID="{CD000000-8B95-11D1-82DB-00C04FB1625D}" -->
<%
'메일 보내기 시작
Dim UserID, UserName, imgURL
Dim Fso, ts, strPath, strHTML
Dim iMsg, iConf, Flds
Dim MailTo, MailFrom, MailSubject, MailBody

UserID = Request("UserID")
UserName = Request("UserName")
imgURL = "http://www.xxx.com/"

MailTo = ""
MailFrom = ""
MailSubject = ""

'HTML 파일 읽어오기
Set Fso=CreateObject("Scripting.FileSystemObject")
strPath=Server.MapPath("/info_mail/c_finish.htm")
Set ts = Fso.OpenTextFile(strPath)

 Do While Not ts.AtEndOfStream
  MailBody = MailBody & ts.ReadLine & Chr(13) & Chr(10)
 Loop

Set ts = Nothing
Set Fso = Nothing  
 
'HTML 소스내의 특정문자열을 현재 사용자 정보로 치환
MailBody = Replace(MailBody,"[UserID]",UserID)
MailBody = Replace(MailBody,"[UserName]", UserName)
MailBody = Replace(MailBody,"[url]",imgURL)

Set iMsg = CreateObject("CDO.Message")
Set iConf = CreateObject("CDO.Configuration")
Set Flds = iConf.Fields
   
 With Flds
  .Item(cdoSendUsingMethod) = 1
  .Item(cdoSMTPServerPickupDirectory) = "c:\Inetpub\mailroot\Pickup"
  .Item(cdoSMTPConnectionTimeout) = 30
  .Item(cdoSMTPServer) = "localhost"
  .Update
 End With

 With iMsg
  Set .Configuration = iConf
  .To = MailTo
  .From = MailFrom
  .Subject = MailSubject
  .HTMLBody = MailBody
  .Send
 End With

Set iMsg = Nothing
Set iConf = Nothing
Set Flds = Nothing
'메일 보내기 끝
%>